| # Add --enable-maintainer-mode option to configure. -*- Autoconf -*- |
| # From Jim Meyering |
| |
| # Copyright (C) 1996-2013 Free Software Foundation, Inc. |
| # |
| # This file is free software; the Free Software Foundation |
| # gives unlimited permission to copy and/or distribute it, |
| # with or without modifications, as long as this notice is preserved. |
| |
| # AM_MAINTAINER_MODE([DEFAULT-MODE]) |
| # ---------------------------------- |
| # Control maintainer-specific portions of Makefiles. |
| # Default is to disable them, unless 'enable' is passed literally. |
| # For symmetry, 'disable' may be passed as well. Anyway, the user |
| # can override the default with the --enable/--disable switch. |
| AC_DEFUN([AM_MAINTAINER_MODE], |
| [m4_case(m4_default([$1], [disable]), |
| [enable], [m4_define([am_maintainer_other], [disable])], |
| [disable], [m4_define([am_maintainer_other], [enable])], |
| [m4_define([am_maintainer_other], [enable]) |
| m4_warn([syntax], [unexpected argument to AM@&t@_MAINTAINER_MODE: $1])]) |
| AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles]) |
| dnl maintainer-mode's default is 'disable' unless 'enable' is passed |
| AC_ARG_ENABLE([maintainer-mode], |
| [AS_HELP_STRING([--]am_maintainer_other[-maintainer-mode], |
| am_maintainer_other[ make rules and dependencies not useful |
| (and sometimes confusing) to the casual installer])], |
| [USE_MAINTAINER_MODE=$enableval], |
| [USE_MAINTAINER_MODE=]m4_if(am_maintainer_other, [enable], [no], [yes])) |
| AC_MSG_RESULT([$USE_MAINTAINER_MODE]) |
| AM_CONDITIONAL([MAINTAINER_MODE], [test $USE_MAINTAINER_MODE = yes]) |
| MAINT=$MAINTAINER_MODE_TRUE |
| AC_SUBST([MAINT])dnl |
| ] |
| ) |
