chromium/src/third_party/blink/renderer/core/probe/BUILD.gn

# Copyright 2017 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//third_party/blink/renderer/core/core.gni")

action("instrumentation_probes") {
  script = "../../build/scripts/make_instrumenting_probes.py"

  inputs = [
    "core_probes.pidl",
    "core_probes.json5",
    "../../build/scripts/templates/instrumenting_probes_impl.cc.tmpl",
    "../../build/scripts/templates/instrumenting_probes_inl.h.tmpl",
    "../../build/scripts/templates/probe_sink.h.tmpl",
  ]

  outputs = [
    "$blink_core_output_dir/core_probes_inl.h",
    "$blink_core_output_dir/core_probes_impl.cc",
    "$blink_core_output_dir/core_probe_sink.h",
  ]

  args = [
    rebase_path(inputs[0], root_build_dir),
    "--config",
    rebase_path("core_probes.json5", root_build_dir),
    "--output_dir",
    rebase_path(blink_core_output_dir, root_build_dir),
  ]
}

source_set("generated") {
  deps = [ ":instrumentation_probes" ]
}

# Compiles the sources generated above.
blink_core_sources("probe") {
  configs += [ "//build/config/compiler:noshadowing" ]

  sources = [
    "async_task_id.h",
    "core_probes.cc",
    "core_probes.h",
  ]
  sources += get_target_outputs(":instrumentation_probes")

  deps = [
    ":instrumentation_probes",
    "//skia",
    "//third_party/blink/renderer/bindings/core/v8:bindings_core_v8_generated",
    "//third_party/blink/renderer/core:all_generators",
    "//third_party/blink/renderer/platform:make_platform_generated",
    "//third_party/blink/renderer/platform/wtf",
    "//v8",
  ]
}